home *** CD-ROM | disk | FTP | other *** search
/ Softdisk G-S 156 / SGDS 156.2mg / SDGS.156 / A / CT.CONCLUSION (.txt) < prev    next >
Encoding:
Applesoft BASIC Source Code  |  1994-08-12  |  2.0 KB  |  40 lines  |  [FC] Applesoft BASIC Program (0x0A01)
  1. 10  PRINT "   You return to the New Kingdom where you are eagerly received at the Palace.": PRINT 
  2. 20 R4 = A%(65,4): IF R4 = 50  THEN  PRINT "  They're sorry you didn't find the rod.  They thank you for trying and solemnly prepare for the end.": PRINT : PRINT : GOTO 32050
  3. 30  IF R4 =  -1  OR (R4 =  -2  AND M%(2,5) = 1)  OR (R4 =  -5  AND M%(5,5) = 1)  THEN 50
  4. 40  PRINT "  They're sorry you weren't able to bring the rod out of the castle.  How close you came -- actually finding it, then losing it.  Solemnly they prepare for the end.": PRINT : PRINT : GOTO 32050
  5. 50  PRINT "   They see that you have the rod.  Relief, then ecstasy, sweeps the Court.": PRINT 
  6. 55 A%(65,4) = 0
  7. 60  PRINT "   'You have won great battles, solved great mysteries, and saved our nation....again!  Truly yours will be a name remembered for all time.'": PRINT 
  8. 70  PRINT "   'And, I see, you made a bit of money out of it all.....'": PRINT :TV = 1: GOTO 32050
  9. 100  REM  DIE - COMPANIONS SURVIVE
  10. 110  VTAB 5: PRINT "  The enemy was defeated, but your companions can do nothing except bury you.": PRINT : PRINT 
  11. 120  GOTO 32000
  12. 200  REM  DIE - COMPANIONS WIPED OUT
  13. 210  VTAB 5: PRINT "          Your companions fought on bravely but eventually succumbed.": PRINT : PRINT 
  14. 220  GOTO 32000
  15. 300  REM  DIE - YOU WERE THE LAST
  16. 310  VTAB 5: PRINT "  As the light fades from your eyes, you wish you had done things differently.": PRINT : PRINT 
  17. 320  GOTO 32000
  18. 32000 DI = 1
  19. 32050  REM 
  20. 32080  INVERSE : PRINT  SPC( 70);: NORMAL : PRINT " THE END.": PRINT : PRINT : IF   NOT DI  THEN 32500
  21. 32100  VTAB 20: PRINT "TRY AGAIN? Y/N:  ";
  22. 32110  GET A$: IF A$ < >"Y"  AND A$ < >"y"  AND A$ < >"N"  AND A$ < >"n"  THEN 32110
  23. 32120  PRINT A$: PRINT : IF A$ = "N"  OR A$ = "n"  THEN  PRINT  CHR$(4)"BYE"
  24. 32130  PRINT D$"RUN CT.INTRO"
  25. 32500  REM  ASSESS SCORE
  26. 32600  PRINT "                               BATTLE POINTS: ";TB%(0)
  27. 32700  IF TV  THEN  PRINT "                        BONUS: KINGDOM SAVED: 1000":TB%(0) = TB%(0) +1000
  28. 32810  FOR A = 1 TO NA: IF   NOT A%(A,1)  THEN  NEXT : GOTO 32860
  29. 32820 R4 = A%(A,4)
  30. 32830  IF R4 > -1  OR R4 < -5  THEN  NEXT : GOTO 32860
  31. 32840 DF =  ABS(R4): IF M%(DF,5) < >1  THEN  NEXT : GOTO 32860
  32. 32850 TG = TG +A%(A,1): NEXT 
  33. 32860 PC = TG/1435:PC =  INT(PC *100): IF PC >100  THEN PC = 100
  34. 32870  PRINT "                   BONUS: TREASURE RECOVERED: ";:GB = TG: PRINT  SPC( GB <1000) SPC( GB <100) SPC( GB <10)GB;"  ---> ";PC;"%":TB%(0) = TB%(0) +GB
  35. 32900  PRINT "                                 TOTAL SCORE: ";TB%(0)
  36. 32910  PRINT : INVERSE : PRINT  SPC( 80);: NORMAL 
  37. 32920  PRINT : IF   NOT TV  THEN 32100
  38. 32950  PRINT : PRINT "Congratulations, ";M$(1);"!"
  39. 32960  PRINT : PRINT "Press a key...": GET A$
  40. 32990  PRINT  CHR$(4)"BYE"